home *** CD-ROM | disk | FTP | other *** search
/ Linux Cubed Series 7: Sunsite / Linux Cubed Series 7 - Sunsite Vol 1.iso / system / network / manageme / tcpdump-.001 / tcpdump-~ / tcpdump-3.0.2-linux / tcpdump-3.0.2 / configure < prev    next >
Encoding:
Text File  |  1995-09-30  |  3.0 KB  |  132 lines
  1. #!/bin/csh -f
  2. if ( ! -d libpcap || ! -r libpcap/libpcap.a ) then
  3.     set libpcapdir
  4.     set dir=`ls .. | sed -e 's/\/$//' | egrep '^libpcap-[0-9]*\.[0-9]*(\.[0-9]*)?([ab])?$'`
  5.     if ( $#dir > 1 ) set dir="$dir[$#dir]"
  6.     foreach d ( /usr/lib /usr/local/lib ../libpcap ../$dir )
  7.         if ( -d $d && -r $d/libpcap.a ) then
  8.             set libpcapdir=$d
  9.             break
  10.         endif
  11.     end
  12.     if ( "$libpcapdir" == "" ) then
  13.         echo "configure: can't find libpcap.a"
  14.         echo "configure: (see the README for more info)"
  15.         exit 1
  16.     endif
  17.     if ( "$libpcapdir" != "/usr/lib" && \
  18.         "$libpcapdir" != "/usr/local/lib" ) then
  19.         rm -rf libpcap
  20.         ln -s $libpcapdir libpcap
  21.         echo "configure: using libpcap.a installed in $libpcapdir"
  22.     endif
  23. endif
  24. if ( -x /bin/uname || -x /usr/bin/uname ) then
  25.     set md=`uname -m`
  26.     set name=`uname -s | tr '[A-Z]' '[a-z]'`
  27.     set vers=`uname -r | sed -e 's/\..*//' -e 's/T1/v1/' | tr '[A-Z]' '[a-z]'`
  28.     if ( "$name$vers" == "sunos5") then
  29.         set path=($path /usr/ccs/bin)
  30.     endif
  31.     if ( "$name" == "linux" ) then
  32.         set vers=
  33.     endif
  34. else if ( -x /bin/arch ) then
  35.     # sun3 only supported machine without uname
  36.     if ( `/bin/arch` != sun3 ) goto bail
  37.     set md=sun3
  38.     set name=sunos
  39.     set vers=3
  40. else
  41.     goto bail
  42. endif
  43. if ( $name == "bsd/386" || $name == "bsd/os" ) then
  44.     set os=bsd
  45. else
  46.     set os=$name$vers
  47. endif
  48. switch ( $md )
  49.     case alpha:
  50.     case i386:
  51.     case i486:
  52.     case i586:
  53.     case i686:
  54.         breaksw
  55.  
  56.     case sun3:
  57.         set md=sun3
  58.         breaksw
  59.  
  60.     case sparc:
  61.     case sun4*:
  62.         set md=sun4
  63.         breaksw
  64.  
  65.     case RISC:
  66.         set md=mips
  67.         breaksw
  68.  
  69.     case IP[0-9]*:
  70.         set md=mips
  71.         breaksw
  72.  
  73.     default:
  74.         goto bail
  75.         breaksw
  76. endsw
  77. rm -f Makefile md.h os.h
  78. set bpf
  79. set brokenmake
  80. set cslip
  81. set dnet
  82. set ethers
  83. set gcc
  84. set gcc1
  85. if ( -e /dev/bpf0 ) set bpf='-e s/^#have-bpf#//'
  86. if ( -f /usr/include/net/slip.h ) set cslip='-e s/^#have-cslip#//'
  87. if ( -f /usr/lib/libdnet.a ) set dnet='-e s/^#have-dnet#//'
  88. foreach f ( /usr/lib/libc.a /lib/libc.a /usr/lib/libc_s.a )
  89.     if ( -f $f ) then
  90.         set libc=$f
  91.         break
  92.     endif
  93. end
  94. if ( "$f" == "" ) then
  95.     echo "configure: couldn't find libc"
  96. else
  97.     nm $libc |& grep ether_ntoa > /dev/null
  98.     if ( $status == 0 ) then
  99.         set ethers='-e s/^#have-ethers#//'
  100.         echo "configure: found support for /etc/ethers"
  101.     endif
  102. endif
  103. if ( -x /usr/local/bin/gcc || -x /usr/local/gcc ) then
  104.     set gcc='-e s/^#have-gcc#//'
  105.     set ver=`gcc -v |& sed -n -e '$s/.* //' -e '$s/\..*//p'`
  106.     if ( "$ver" == 1 ) set gcc1='-e s/^#have-gcc1#//'
  107. endif
  108. if ("$os" == "ultrix4" || "$os" == "sunos3") then
  109.     set brokenmake='-e s/^#have-broken-make#//'
  110. endif
  111. if ( ! -f /usr/include/stdlib.h ) ln -s /dev/null stdlib.h
  112. if ( ! -f md-$md.h ) then
  113.     echo "configure: unsupported machine type $md"
  114.     exit 1
  115. endif
  116. ln -s md-$md.h md.h
  117. if ( ! -f os-$os.h ) then
  118.     echo "configure: unsupported os type $os"
  119.     exit 1
  120. endif
  121. ln -s os-$os.h os.h
  122. sed -e "s/^#have-$md-$os#//" -e "s/^#have-$os#//" \
  123.     $bpf $cslip $gcc $gcc1 $ethers $dnet $brokenmake Makefile.in > Makefile
  124. set mflags=""
  125. if ( "$gcc" != "" ) set mflags="CC=gcc"
  126. chmod ug+w Makefile
  127. make depend $mflags
  128. exit 0
  129. bail:
  130. echo 'configure: unsupported system'
  131. exit 1
  132.